@ECHO OFF
CHCP 1252 1>NUL
TITLE WinXP-IE - 360 Extreme Explorer Uninstaller
PushD "%~dp0"
If "%Processor_Architecture%" == "x86" (Set "PFD=%ProgramFiles%") Else (Set "PFD=%ProgramFiles(x86)%")

If "%~1"=="/uninstall" GoTo UNINSTALL

ECHO                                      \\!//
ECHO                                      (o o)
ECHO ---------------------------------oOOo-(_)-oOOo---------------------------------
ECHO                      Uninstalling of 360 Extreme Explorer
ECHO ===============================================================================
FLTMC >NUL 2>&1 || Set _=^"Set "_ELEV=1" ^& CD /d """%~dp0""" ^& "%~f0" %*^" && ((If "%_ELEV%"=="" (ECHO. & ECHO Requesting administrator privileges . . . & ((PowerShell -nop -c START "" CMD -args '/d/x/s/v:off/r',$env:_ -Verb RunAs >NUL 2>NUL) || (mshta vbscript:execute^("CreateObject(""Shell.Application"").ShellExecute(""CMD"",""/d/x/s/v:off/r"" & CreateObject(""WScript.Shell"").Environment(""PROCESS"")(""_""),,""RunAs"",1)(Window.Close)"^) >NUL 2>&1))) Else (ECHO. & ECHO This script requires administrator privileges. & PAUSE)) & EXIT /b)
ping -n 1 localhost 1>NUL

ECHO.
ECHO Do you want to Uninstall the 360 Extreme Explorer internet browser?
ECHO.
PAUSE

ECHO.
ECHO -------------------------------------------------------------------------------

ECHO.
ECHO Copying file "Uninstaller.cmd" into the folder
ECHO "%Temp%" . . .
XCOPY ".\Uninstaller.cmd" "%Temp%\" /V /Y /Z 1>NUL
ECHO.
ECHO Executing file "Uninstaller.cmd" from the folder
ECHO "%Temp%" . . .
CALL "%Temp%\Uninstaller.cmd" /uninstall
EXIT

:UNINSTALL

ECHO.
ECHO ---------------------------------[ Removing ]----------------------------------
ping -n 3 localhost 1>NUL

ECHO.
ECHO Deleting 360 Extreme Explorer shortcuts . . .
DEL /f "%AllUsersProfile%\Start Menu\Programs\360EE Chrome.lnk" 2>NUL
DEL /f "%AllUsersProfile%\Desktop\360EE Chrome.lnk" 2>NUL
DEL /f "%AllUsersProfile%\Application Data\Microsoft\Internet Explorer\Quick Launch\360EE Chrome.lnk" 2>NUL
DEL /f "%UserProfile%\Start Menu\Programs\360EE Chrome.lnk" 2>NUL
DEL /f "%UserProfile%\Desktop\360EE Chrome.lnk" 2>NUL
DEL /f "%AppData%\Microsoft\Internet Explorer\Quick Launch\360EE Chrome.lnk" 2>NUL

TaskList /nh | FindStr /l /i "360chrome.exe" >NUL 2>&1 || GoTo SKIP
ECHO.
ECHO Terminating 360 Extreme Explorer processes . . .
TaskKill /f /im "360chrome.exe" >NUL 2>&1
ping -n 6 localhost 1>NUL
:SKIP

ECHO.
ECHO Deleting 360 Extreme Explorer files . . .
RmDir /s /q "%PFD%\360EE Chrome" 2>NUL
RmDir /s /q "%UserProfile%\Local Settings\Application Data\360EE Chrome" 2>NUL

ECHO.
ECHO Deleting 360 Extreme Explorer registry entries . . .
Reg Delete "HKCU\Software\360Chrome" /f >NUL 2>&1
Reg Delete "HKCU\Software\MozillaPlugins" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\360Chrome" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\MozillaPlugins" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Microsoft\ESENT\Process\360chrome" /f >NUL 2>&1
Reg Add "HKLM\SOFTWARE\Classes\.htm" /ve /t REG_SZ /d "htmlfile" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\.html" /ve /t REG_SZ /d "htmlfile" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\.shtml" /ve /f 1>NUL
Reg Delete "HKLM\SOFTWARE\Classes\.shtml" /v "Content Type" /f 1>NUL
Reg Delete "HKLM\SOFTWARE\Classes\.pdf" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\.svg" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\.webp" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\.xht" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\.xhtml" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\360ChromeHTML" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\360ChromeURL" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\Classes\Applications\360chrome.exe" /f >NUL 2>&1
::Reg Add "HKLM\SOFTWARE\Classes\ftp\DefaultIcon" /ve /t REG_EXPAND_SZ /d "%%"SystemRoot"%%\system32\url.dll,0" /f 1>NUL
::Reg Add "HKLM\SOFTWARE\Classes\ftp\shell\open\command" /ve /t REG_SZ /d "\"%PFD%\Internet Explorer\IEXPLORE.EXE\" %1" /f 1>NUL
::Reg Add "HKLM\SOFTWARE\Classes\ftp\shell\open\ddeexec" /ve /t REG_SZ /d "\"%%1\",,-1,0,,,," /f 1>NUL
::Reg Add "HKLM\SOFTWARE\Classes\ftp\shell\open\ddeexec" /v "NoActivateHandler" /t REG_SZ /d "" /f 1>NUL
::Reg Add "HKLM\SOFTWARE\Classes\ftp\shell\open\ddeexec\Application" /ve /t REG_SZ /d "IExplore" /f 1>NUL
::Reg Add "HKLM\SOFTWARE\Classes\ftp\shell\open\ddeexec\ifExec" /ve /t REG_SZ /d "*" /f 1>NUL
::Reg Add "HKLM\SOFTWARE\Classes\ftp\shell\open\ddeexec\Topic" /ve /t REG_SZ /d "WWW_OpenURL" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\http\DefaultIcon" /ve /t REG_EXPAND_SZ /d "%%"SystemRoot"%%\system32\url.dll,0" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\http\shell\open\command" /ve /t REG_SZ /d "\"%PFD%\Internet Explorer\IEXPLORE.EXE\" -nohome" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\http\shell\open\ddeexec" /ve /t REG_SZ /d "\"%%1\",,-1,0,,,," /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\http\shell\open\ddeexec" /v "NoActivateHandler" /t REG_SZ /d "" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\http\shell\open\ddeexec\Application" /ve /t REG_SZ /d "IExplore" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\http\shell\open\ddeexec\Topic" /ve /t REG_SZ /d "WWW_OpenURL" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\https\DefaultIcon" /ve /t REG_EXPAND_SZ /d "%%"SystemRoot"%%\system32\url.dll,0" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\https\shell\open\command" /ve /t REG_SZ /d "\"%PFD%\Internet Explorer\IEXPLORE.EXE\" -nohome" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\https\shell\open\ddeexec" /ve /t REG_SZ /d "\"%%1\",,-1,0,,,," /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\https\shell\open\ddeexec" /v "NoActivateHandler" /t REG_SZ /d "" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\https\shell\open\ddeexec\Application" /ve /t REG_SZ /d "IExplore" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Classes\https\shell\open\ddeexec\Topic" /ve /t REG_SZ /d "WWW_OpenURL" /f 1>NUL
Reg Add "HKLM\SOFTWARE\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f 1>NUL
Reg Delete "HKLM\SOFTWARE\Clients\StartMenuInternet\360CHROME.EXE" /f >NUL 2>&1
Reg Delete "HKLM\SOFTWARE\RegisteredApplications" /v "360 Extreme Explorer" /f >NUL 2>&1
If Exist "%SystemRoot%\system32\Macromed\Flash\NPSWF32_*.dll" Reg Add "HKLM\SOFTWARE\Classes\MacromediaFlashPaper.MacromediaFlashPaper\DefaultIcon" /ve /t REG_SZ /d "%PFD%\Internet Explorer\iexplore.exe,1" /f 1>NUL
If Exist "%SystemRoot%\system32\Macromed\Flash\NPSWF32_*.dll" Reg Add "HKLM\SOFTWARE\Classes\MacromediaFlashPaper.MacromediaFlashPaper\shell\open\command" /ve /t REG_SZ /d "\"%PFD%\Internet Explorer\iexplore.exe\" -nohome \"%%1\"" /f 1>NUL
If Not Exist "%SystemRoot%\system32\Macromed\Flash\NPSWF32_*.dll" Reg Delete "HKLM\SOFTWARE\Classes\MacromediaFlashPaper.MacromediaFlashPaper" /f >NUL 2>&1

ECHO.
ECHO ----------------------------------[ Finished ]---------------------------------
If Not Exist "%PFD%\360EE Chrome\Uninstaller.cmd" Reg Delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\360 Extreme Explorer" /f >NUL 2>&1
ping -n 5 localhost 1>NUL
DEL /f %0 2>NUL