@ECHO OFF
TITLE WinXP-IE - Paragon GPT Loader Installer
PushD "%~dp0"

:: Paragon GPT Loader:
Set "VERSION=11.0.0.175"

ECHO                                      \\!//
ECHO                                      (o o)
ECHO ---------------------------------oOOo-(_)-oOOo---------------------------------
ECHO              Installation of Toshiba Paragon GPT Loader v%VERSION%
ECHO ===============================================================================
FLTMC >NUL 2>&1 || Set _=^"Set "_ELEV=1" ^& CD /d """%~dp0""" ^& "%~f0" %*^" && ((If "%_ELEV%"=="" (ECHO. & ECHO Requesting administrator privileges . . . & ((PowerShell -nop -c START "" CMD -args '/d/x/s/v:off/r',$env:_ -Verb RunAs >NUL 2>NUL) || (mshta vbscript:execute^("CreateObject(""Shell.Application"").ShellExecute(""CMD"",""/d/x/s/v:off/r"" & CreateObject(""WScript.Shell"").Environment(""PROCESS"")(""_""),,""RunAs"",1)(Window.Close)"^) >NUL 2>&1))) Else (ECHO. & ECHO This script requires administrator privileges. & PAUSE)) & EXIT /b)
ping -n 1 localhost 1>NUL

VER | FindStr /l /i "5.1" 1>NUL && GoTo CorrectOS
COLOR 0C
ECHO.
ECHO ERROR: This Operating System is not Supported.
ECHO ERROR: This Paragon GPT Loader v%VERSION% is only for Windows XP 32-bit.
ECHO.
PAUSE
EXIT

:CorrectOS
If "%~1"=="/passive" Set "AutoRun=YES" & GoTo SKIP
ECHO.
ECHO Do you want to INSTALL the Paragon GPT Loader driver?
ECHO.
PAUSE

ECHO.
ECHO --------------------------------[ Installing ]---------------------------------
:SKIP

ECHO.
ECHO Installing Paragon GPT Loader driver, Please Wait . . .
RunDll32.exe SetupAPI.dll,InstallHinfSection DefaultInstall 128 .\gptmount.inf

ECHO.
ECHO ---------------------------------[ Finished ]----------------------------------
If "%AutoRun%"=="YES" (ping -n 5 localhost 1>NUL & EXIT) Else (ECHO. & PAUSE)